vss_25.0.0_1ddbb26c/tools/ucd/ucd-derived_east_asian_width_loader.adb

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
--
--  Copyright (C) 2023-2024, AdaCore
--
--  SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
--

with Ada.Wide_Wide_Text_IO;

with UCD.Characters;
with UCD.Data_File_Loaders;
with UCD.Properties;

package body UCD.Derived_East_Asian_Width_Loader is

   ----------
   -- Load --
   ----------

   procedure Load (UCD_Root : Wide_Wide_String) is
      EA_Property : constant not null UCD.Properties.Property_Access :=
        UCD.Properties.Resolve ("ea");
      Value_Field  : constant Data_File_Loaders.Field_Index := 1;
      --  Index of the data field with the value of the property.

      Loader       : UCD.Data_File_Loaders.File_Loader;

   begin
      Loader.Open (UCD_Root, "extracted/DerivedEastAsianWidth.txt");

      while not Loader.End_Of_File loop
         declare
            First_Code : UCD.Code_Point;
            Last_Code  : UCD.Code_Point;

         begin
            Loader.Get_Code_Point_Range (First_Code, Last_Code);

            if Loader.Is_Missing then
               Ada.Wide_Wide_Text_IO.Put_Line
                 ("  - set to '" & Loader.Get_Field (1, True)
                  & "' in " & Loader.Get_Field (0, True));
            end if;

            declare
               Value : constant not null Properties.Property_Value_Access :=
                 UCD.Properties.Resolve
                   (EA_Property, Loader.Get_Field (Value_Field, True));

            begin
               for Code in First_Code .. Last_Code loop
                  UCD.Characters.Set (Code, EA_Property, Value);
               end loop;
            end;

            Loader.Skip_Line;
         end;
      end loop;
   end Load;

end UCD.Derived_East_Asian_Width_Loader;