1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174 | ------------------------------------------------------------------------------
-- --
-- Copyright (C) 2015, AdaCore --
-- --
-- Redistribution and use in source and binary forms, with or without --
-- modification, are permitted provided that the following conditions are --
-- met: --
-- 1. Redistributions of source code must retain the above copyright --
-- notice, this list of conditions and the following disclaimer. --
-- 2. Redistributions in binary form must reproduce the above copyright --
-- notice, this list of conditions and the following disclaimer in --
-- the documentation and/or other materials provided with the --
-- distribution. --
-- 3. Neither the name of STMicroelectronics nor the names of its --
-- contributors may be used to endorse or promote products derived --
-- from this software without specific prior written permission. --
-- --
-- THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS --
-- "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT --
-- LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR --
-- A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT --
-- HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, --
-- SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT --
-- LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, --
-- DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY --
-- THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT --
-- (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE --
-- OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. --
-- --
-- --
-- This file is based on: --
-- --
-- @file stm32f4xx_hal_rng.c --
-- @author MCD Application Team --
-- @version V1.1.0 --
-- @date 19-June-2014 --
-- @brief RNG HAL module driver. --
-- --
-- COPYRIGHT(c) 2014 STMicroelectronics --
------------------------------------------------------------------------------
with Ada.Interrupts.Names;
package body STM32.RNG.Interrupts is
type Buffer_Content is array (Integer range <>) of UInt32;
type Ring_Buffer is record
Content : Buffer_Content (0 .. 9);
Head : Integer := 0;
Tail : Integer := 0;
end record;
--------------
-- Receiver --
--------------
protected Receiver is
pragma Interrupt_Priority;
entry Get_Random_32 (Value : out UInt32);
private
Last : UInt32 := 0;
Buffer : Ring_Buffer;
Data_Available : Boolean := False;
procedure Interrupt_Handler;
pragma Attach_Handler
(Interrupt_Handler,
Ada.Interrupts.Names.HASH_RNG_Interrupt);
end Receiver;
--------------
-- Receiver --
--------------
protected body Receiver is
-------------------
-- Get_Random_32 --
-------------------
entry Get_Random_32 (Value : out UInt32) when Data_Available is
Next : constant Integer :=
(Buffer.Tail + 1) mod Buffer.Content'Length;
begin
-- Remove an item from our ring buffer.
Value := Buffer.Content (Next);
Buffer.Tail := Next;
-- If the buffer is empty, make sure we block subsequent callers
-- until the buffer has something in it.
if Buffer.Tail = Buffer.Head then
Data_Available := False;
end if;
Enable_RNG;
end Get_Random_32;
-----------------------
-- Interrupt_Handler --
-----------------------
procedure Interrupt_Handler is
Current : UInt32;
begin
if RNG_Seed_Error_Status then
Clear_RNG_Seed_Error_Status;
-- Clear then set the RNGEN bit to reinitialize and restart
-- the RNG.
Reset_RNG;
end if;
if RNG_Clock_Error_Status then
-- TODO: reconfigure the clock and make sure it's okay
-- Clear the bit.
Clear_RNG_Clock_Error_Status;
end if;
if RNG_Data_Ready then
Current := RNG_Data;
if Current /= Last then
-- This number is good.
if (Buffer.Head + 1) mod Buffer.Content'Length = Buffer.Tail
then
-- But our buffer is full. Turn off the RNG.
Disable_RNG;
else
-- Add this new data to our buffer.
Buffer.Head := (Buffer.Head + 1) mod Buffer.Content'Length;
Buffer.Content (Buffer.Head) := Current;
Data_Available := True;
Last := Current;
end if;
end if;
end if;
end Interrupt_Handler;
end Receiver;
--------------------
-- Initialize_RNG --
--------------------
procedure Initialize_RNG is
Discard : UInt32;
begin
Enable_RNG_Clock;
Enable_RNG_Interrupt;
Enable_RNG;
-- Discard the first randomly generated number, according to STM32F4
-- docs.
Receiver.Get_Random_32 (Discard);
end Initialize_RNG;
------------
-- Random --
------------
function Random return UInt32 is
Result : UInt32;
begin
Receiver.Get_Random_32 (Result);
return Result;
end Random;
end STM32.RNG.Interrupts;
|